Tag Archive for 'Papervision Tutorial'

Adding XML to the Papervision Coverflow

Published

on December 26, 2009

in Actionscript 3 Papervision, Actionscript 3.0, Examples, Flash, Loading XML, Papervision 3D, Papervision Coverflow, Source Code and Tutorials

. 11 Comments

As a simple addition to yesterday's coverflow post, I wanted to show the same example but with loading images via XML. For simplicity sake the XML is loaded and parsed all in the main file.

The structure for our XML is very simple:

PLAIN TEXT

XML:

<?xml version="1.0" encoding="utf-8" ?>
<data>
<image><![CDATA[images/image1.jpg]]></image>
<image><![CDATA[images/image2.jpg]]></image>
<image><![CDATA[images/image3.jpg]]></image>
<image><![CDATA[images/image5.jpg]]></image>
<image><![CDATA[images/image4.jpg]]></image>
<image><![CDATA[images/image6.jpg]]></image>
<image><![CDATA[images/image7.jpg]]></image>
</data>

We simply load our XML file with BulkLoader

PLAIN TEXT

Actionscript:

protected function loadXML():void
{
bulkInstance = new BulkLoader("bulkInstance");
bulkInstance.add(xmlPath);
bulkInstance.addEventListener(BulkProgressEvent.COMPLETE, onXMLReady);
bulkInstance.start();
}

Parse the results, now adding the images to the BulkLoader:

PLAIN TEXT

Actionscript:

protected function onXMLReady(evt:BulkProgressEvent):void
{
bulkInstance.removeEventListener(BulkProgressEvent.COMPLETE, onXMLReady);
bulkInstance.addEventListener(BulkProgressEvent.COMPLETE, onImagesReady);
var xml:XML = bulkInstance.getXML(xmlPath);
var xmlList:XMLList = xml.image;
for (var i:int = 0; i <xmlList.length(); i++)
{
var imagePath:String = String(xmlList[i])
bulkInstance.add(imagePath);
//Add path to array for later access
images.push(imagePath);
}
//Set our number of items based on how many images we load
numItems = images.length;
}

When our images are ready we can continue the process of setting up our coverflow. But now using the images we just loaded for our materials.

PLAIN TEXT

Actionscript:

var mat:BitmapMaterial = new BitmapMaterial(bulkInstance.getBitmapData(images[i]));

It's that simple. Be sure to let us know if you find this useful and are able to use it in a project.

Here is the full code:

PLAIN TEXT

Actionscript:

package
{
import br.com.stimuli.loading.BulkLoader;
import br.com.stimuli.loading.BulkProgressEvent;
import flash.display.Sprite;
import flash.events.MouseEvent;
import flash.filters.GlowFilter;
import gs.easing.Quint;
import gs.TweenLite;
import org.papervision3d.events.InteractiveScene3DEvent;
import org.papervision3d.materials.BitmapMaterial;
import org.papervision3d.objects.DisplayObject3D;
import org.papervision3d.objects.primitives.Plane;
import org.papervision3d.view.BasicView;
/**
* ...
* @author Charlie Schulze, charlie[at]woveninteractive[dot]com
* Licensed under the MIT license: http://www.opensource.org/licenses/mit-license.php
*/
public class Main extends BasicView
{
protected var planes:Array = [];
protected var images:Array = [];
protected var numItems:Number;
protected var currentItem:Number = 3;
protected var angle:Number = 25;
protected var rightBtn:Sprite;
protected var leftBtn:Sprite;
protected var xmlPath:String = "xml/imageXML.xml";
protected var bulkInstance:BulkLoader;
public function Main():void
{
//Make sure that your scene is set to interactive
super(640, 480, true, true);
loadXML();
}
//First load our XML
protected function loadXML():void
{
bulkInstance = new BulkLoader("bulkInstance");
bulkInstance.add(xmlPath);
bulkInstance.addEventListener(BulkProgressEvent.COMPLETE, onXMLReady);
bulkInstance.start();
}
//When our xml is ready parse and load our images
protected function onXMLReady(evt:BulkProgressEvent):void
{
bulkInstance.removeEventListener(BulkProgressEvent.COMPLETE, onXMLReady);
bulkInstance.addEventListener(BulkProgressEvent.COMPLETE, onImagesReady);
var xml:XML = bulkInstance.getXML(xmlPath);
var xmlList:XMLList = xml.image;
for (var i:int = 0; i <xmlList.length(); i++)
{
var imagePath:String = String(xmlList[i])
bulkInstance.add(imagePath);
//Add path to array for later access
images.push(imagePath);
}
//Set our number of items based on how many images we load
numItems = images.length;
}
//Images are finished loading we can now create our papervision coverflow
protected function onImagesReady(evt:BulkProgressEvent):void
{
init();
}
protected function init():void
{
createChildren();
createNavigation();
animate();
startRendering();
}
protected function createChildren():void
{
for (var i:int = 0; i <numItems; i++)
{
//Grab our bitmapData from the bulkLoader using our array of image paths as our key
var mat:BitmapMaterial = new BitmapMaterial(bulkInstance.getBitmapData(images[i]));
mat.interactive = true;
mat.smooth = true;
var plane:Plane = new Plane(mat, 280, 351, 4, 4);
planes.push(plane);
//Click straight to any plane
plane.addEventListener(InteractiveScene3DEvent.OBJECT_PRESS, onPlaneClick);
//Set an id to target current item
plane.id = i;
//Add plane to the scene
scene.addChild(plane);
}
camera.zoom = 50;
}
protected function onPlaneClick(evt:InteractiveScene3DEvent):void
{
currentItem = evt.target.id;
animate();
}
//Animate the coverflow left / right based off of currentItems
protected function animate():void
{
for (var i:int = 0; i <planes.length; i++)
{
var plane:Plane = planes[i];
//Each if statement will adjust these numbers as needed
var planeX:Number = 0;
var planeZ:Number = -50;
var planeRotationY:Number = 0
//Place & Animate Center Item
if (i == currentItem)
{
planeZ = -300
TweenLite.to(plane, 1, { rotationY:planeRotationY,x:planeX,z:planeZ, ease:Quint.easeInOut } );
}
//Place & Animate Right Items
if(i> currentItem)
{
planeX = (i - currentItem + 1) * 120;
planeRotationY = angle + 10 * (i - currentItem);
TweenLite.to(plane, 1, { rotationY:planeRotationY,x:planeX,z:planeZ, ease:Quint.easeInOut } );
}
//Place & Animate Left Items
if (i <currentItem)
{
planeX = (currentItem - i + 1) * -120;
planeRotationY = -angle - 10 * (currentItem - i);
TweenLite.to(plane, 1, { rotationY:planeRotationY,x:planeX,z:planeZ, ease:Quint.easeInOut } );
}
}
}
/*
* Everything below this point is just for creating the buttons and
* setting button events for controlling the coverflow.
*/
protected function createNavigation():void
{
//Create / Add Buttons
rightBtn = createButton();
leftBtn = createButton();
addChild(leftBtn);
addChild(rightBtn);
//Add button listeners
rightBtn.buttonMode = true;
leftBtn.buttonMode = true;
rightBtn.addEventListener(MouseEvent.CLICK, buttonClick);
leftBtn.addEventListener(MouseEvent.CLICK, buttonClick);
//Place buttons on stage
rightBtn.x = stage.stageWidth - 20;
leftBtn.x = 20;
rightBtn.y = stage.stageHeight / 2;
leftBtn.y = (stage.stageHeight / 2) + 20;
leftBtn.rotation = 180;
}
//Button actions
protected function buttonClick(evt:MouseEvent):void
{
switch (evt.target)
{
case rightBtn:
currentItem ++
break;
case leftBtn:
currentItem --;
break;
}
//Don't allow any number lower than 0 or past max so there
//is always a center item
if (currentItem <0)
{
currentItem = 0;
}
if (currentItem> (planes.length - 1))
{
currentItem = planes.length - 1;
}
//Call animation
animate();
}
//Creates a simple arrow shape / returns the sprite
protected function createButton():Sprite
{
var btn:Sprite = new Sprite();
btn.graphics.beginFill(0x333333);
btn.graphics.moveTo(0, 0);
btn.graphics.lineTo(0, 20);
btn.graphics.lineTo(10, 10);
btn.graphics.lineTo(0, 0);
btn.graphics.endFill();
btn.filters = [new GlowFilter(0xFFFFFF,1,10,10,3)]
return btn;
}
}
}

Delicious Digg This Post Facebook Stumble This Post

A Simple Papervision Coverflow

Published

Charlie

on December 24, 2009

in Actionscript 3 Papervision, Actionscript 3.0, Examples, Papervision 3D, Papervision Coverflow, Tutorials and TweenLite

. 4 Comments

There are several great AS3 / Papervision Coverflows out there but today I set out to create one in it's simplest form. There are no bells and whistles, just a stripped down coverflow with it's core functionality. It's up to you to add an XML feed, Flickr feed, or setup your images in an array and load them the way you want to. This is only meant to be a clean jumping off point.

In the download I have included 2 versions. One with left / right buttons and one without. Both versions you can select the items in the coverflow to navigate.

The heart of this coverflow app is a lot like some of the others. We need to calculate the x and rotation of the center item, left items, and right items are, then animate accordingly. This is the same way that John Dyer animates his coverflow.

PLAIN TEXT

Actionscript:

for (var i:int = 0; i <planes.length; i++)
{
var plane:Plane = planes[i];
//Each if statement will adjust these numbers as needed
var planeX:Number = 0;
var planeZ:Number = 20;
var planeRotationY:Number = 0
//Place & Animate Center Item
if (i == currentItem)
{
planeZ = -300
TweenLite.to(plane, 1, { rotationY:planeRotationY,x:planeX,z:planeZ, ease:Quint.easeInOut } );
}
//Place & Animate Right Items
if(i> currentItem)
{
planeX = (i - currentItem + 1) * 120;
planeRotationY = angle + 10 * (i - currentItem);
TweenLite.to(plane, 1, { rotationY:planeRotationY,x:planeX,z:planeZ, ease:Quint.easeInOut } );
}
//Place & Animate Left Items
if (i <currentItem)
{
planeX = (currentItem - i + 1) * -120;
planeRotationY = -angle - 10 * (currentItem - i);
TweenLite.to(plane, 1, { rotationY:planeRotationY,x:planeX,z:planeZ, ease:Quint.easeInOut } );
}
}

For this simple version of coverflow you have two ways of navigating to items.

Selecting a plane to jump right to that item

PLAIN TEXT

Actionscript:

plane.addEventListener(InteractiveScene3DEvent.OBJECT_PRESS, onPlaneClick);
protected function onPlaneClick(evt:InteractiveScene3DEvent):void
{
currentItem = evt.target.id;
animate();
}

Or using left / right buttons to navigate one item at a time:

PLAIN TEXT

Actionscript:

rightBtn.addEventListener(MouseEvent.CLICK, buttonClick);
leftBtn.addEventListener(MouseEvent.CLICK, buttonClick);
protected function buttonClick(evt:MouseEvent):void
{
switch (evt.target)
{
case rightBtn:
currentItem ++
break;
case leftBtn:
currentItem --;
break;
}
//Don't allow any number lower than 0 or past max so there
//is always a center item
if (currentItem <0)
{
currentItem = 0;
}
if (currentItem> (planes.length - 1))
{
currentItem = planes.length - 1;
}
//Call animation
animate();
}

On to the full source code. This version includes the left / right buttons.

PLAIN TEXT

Actionscript:

package
{
import flash.display.DisplayObject;
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
import flash.filters.GlowFilter;
import gs.easing.Quint;
import gs.TweenLite;
import org.papervision3d.events.InteractiveScene3DEvent;
import org.papervision3d.materials.BitmapFileMaterial;
import org.papervision3d.objects.DisplayObject3D;
import org.papervision3d.objects.primitives.Plane;
import org.papervision3d.view.BasicView;
/**
* ...
* @author Charlie Schulze, charlie[at]woveninteractive[dot]com
* Licensed under the MIT license: http://www.opensource.org/licenses/mit-license.php
*/
public class Main extends BasicView
{
protected var planes:Array = [];
protected var numItems:Number = 7;
protected var currentItem:Number = 3;
protected var angle:Number = 25;
protected var mat:BitmapFileMaterial;
protected var rightBtn:Sprite;
protected var leftBtn:Sprite;
public function Main():void
{
//Make sure that your scene is set to interactive
super(640, 480, true, true);
init();
}
protected function init():void
{
createChildren();
createNavigation();
animate();
startRendering();
}
protected function createChildren():void
{
//Create Material
mat = new BitmapFileMaterial("images/iPhone-back2.png");
mat.smooth = true;
mat.interactive = true;
for (var i:int = 0; i <numItems; i++)
{
var plane:Plane = new Plane(mat, 177, 334, 4, 4);
planes.push(plane);
//Click straight to any plane
plane.addEventListener(InteractiveScene3DEvent.OBJECT_PRESS, onPlaneClick);
//Set an id to target current item
plane.id = i;
//Add plane to the scene
scene.addChild(plane);
}
camera.zoom = 60;
}
protected function onPlaneClick(evt:InteractiveScene3DEvent):void
{
currentItem = evt.target.id;
animate();
}
//Animate the coverflow left / right based off of currentItems
protected function animate():void
{
for (var i:int = 0; i <planes.length; i++)
{
var plane:Plane = planes[i];
//Each if statement will adjust these numbers as needed
var planeX:Number = 0;
var planeZ:Number = -50;
var planeRotationY:Number = 0
//Place & Animate Center Item
if (i == currentItem)
{
planeZ = -300
TweenLite.to(plane, 1, { rotationY:planeRotationY,x:planeX,z:planeZ, ease:Quint.easeInOut } );
}
//Place & Animate Right Items
if(i> currentItem)
{
planeX = (i - currentItem + 1) * 120;
planeRotationY = angle + 10 * (i - currentItem);
TweenLite.to(plane, 1, { rotationY:planeRotationY,x:planeX,z:planeZ, ease:Quint.easeInOut } );
}
//Place & Animate Left Items
if (i <currentItem)
{
planeX = (currentItem - i + 1) * -120;
planeRotationY = -angle - 10 * (currentItem - i);
TweenLite.to(plane, 1, { rotationY:planeRotationY,x:planeX,z:planeZ, ease:Quint.easeInOut } );
}
}
}
/*
* Everything below this point is just for creating the buttons and
* setting button events for controlling the coverflow.
*/
protected function createNavigation():void
{
//Create / Add Buttons
rightBtn = createButton();
leftBtn = createButton();
addChild(leftBtn);
addChild(rightBtn);
//Add button listeners
rightBtn.buttonMode = true;
leftBtn.buttonMode = true;
rightBtn.addEventListener(MouseEvent.CLICK, buttonClick);
leftBtn.addEventListener(MouseEvent.CLICK, buttonClick);
//Place buttons on stage
rightBtn.x = stage.stageWidth - 20;
leftBtn.x = 20;
rightBtn.y = stage.stageHeight / 2;
leftBtn.y = (stage.stageHeight / 2) + 20;
leftBtn.rotation = 180;
}
//Button actions
protected function buttonClick(evt:MouseEvent):void
{
switch (evt.target)
{
case rightBtn:
currentItem ++
break;
case leftBtn:
currentItem --;
break;
}
//Don't allow any number lower than 0 or past max so there
//is always a center item
if (currentItem <0)
{
currentItem = 0;
}
if (currentItem> (planes.length - 1))
{
currentItem = planes.length - 1;
}
//Call animation
animate();
}
//Creates a simple arrow shape / returns the sprite
protected function createButton():Sprite
{
var btn:Sprite = new Sprite();
btn.graphics.beginFill(0x333333);
btn.graphics.moveTo(0, 0);
btn.graphics.lineTo(0, 20);
btn.graphics.lineTo(10, 10);
btn.graphics.lineTo(0, 0);
btn.graphics.endFill();
btn.filters = [new GlowFilter(0xFFFFFF,1,10,10,3)]
return btn;
}
}
}

That's it. This should provide a good base for you to build out your own unique coverflow.

Delicious Digg This Post Facebook Stumble This Post

A Simple Papervision Carousel

Published

Charlie

on December 24, 2009

in 3D Carousel, AS3, Actionscript 3 Papervision, Actionscript 3.0, Papervision, Papervision 3D, Source Code and Tutorials

. 9 Comments

This week I set out to create a Papervision Carousel in it's simplest form. At the heart of this carousel is a simple "for" loop / math which places the items in a circle in 3D space

PLAIN TEXT

Actionscript:

for (var i:int = 0; i <planes.length; i++)
{
var angle:Number = Math.PI * 2 / numItems * i;
var plane:Plane = planes[i];
plane.x = Math.cos(angle) * radius;
plane.z = Math.sin(angle) * radius;
plane.rotationY = -360 / numItems * i - 90;
}

Then to rotate our carousel we apply some similar math

PLAIN TEXT

Actionscript:

var rotateTo:Number = (-360 / numItems) * currentItem + 90;
TweenLite.to(planesHolder, 1, { rotationY:rotateTo, ease:Quint.easeInOut } );

This code allows us to just increment currentItem and rotate our carousel. Another easy add-on would be to setup a navigation along the bottom where you could control and change the currentItem to a specific number to rotate right to that section of the carousel.

It's also very easy to customize the number of items and radius of the carousel by adjusting these numbers.

PLAIN TEXT

Actionscript:

protected var numItems:Number = 20;
protected var radius:Number = 500;

Here is the full code.

PLAIN TEXT

Actionscript:

package
{
import flash.display.DisplayObject;
import flash.display.MovieClip;
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
import gs.easing.Quint;
import gs.TweenLite;
import org.papervision3d.materials.BitmapFileMaterial;
import org.papervision3d.objects.DisplayObject3D;
import org.papervision3d.objects.primitives.Plane;
import org.papervision3d.view.BasicView;
/**
* ...
* @author Charlie Schulze, charlie[at]woveninteractive[dot]com
*/
public class Main extends BasicView
{
protected var planes:Array = [];
protected var numItems:Number = 20;
protected var radius:Number = 500;
protected var currentItem:Number = 0;
protected var mat:BitmapFileMaterial;
protected var planesHolder:DisplayObject3D;
protected var rightBtn:Sprite;
protected var leftBtn:Sprite;
public function Main():void
{
super();
init();
}
protected function init():void
{
createChildren();
createButtons();
commitProperties();
startRendering();
}
protected function createChildren():void
{
planesHolder = new DisplayObject3D();
//Create Material
mat = new BitmapFileMaterial("images/queen.gif");
mat.smooth = true;
mat.doubleSided = true;
for (var i:int = 0; i <numItems; i++)
{
var plane:Plane = new Plane(mat, 150, 234);
planes.push(plane);
//Add plane to the scene
planesHolder.addChild(plane);
}
scene.addChild(planesHolder);
}
protected function commitProperties():void
{
//Set properties of our planes
for (var i:int = 0; i <planes.length; i++)
{
var angle:Number = Math.PI * 2 / numItems * i;
var plane:Plane = planes[i];
plane.x = Math.cos(angle) * radius;
plane.z = Math.sin(angle) * radius;
plane.rotationY = -360 / numItems * i - 90;
}
//Adjust camera
camera.y = 200;
//Rotate once
rotate();
}
//Rotates the carousel
protected function rotate():void
{
var rotateTo:Number = (-360 / numItems) * currentItem + 90;
TweenLite.to(planesHolder, 1, { rotationY:rotateTo, ease:Quint.easeInOut } );
}
/*
* Everything below this point is just for creating the buttons and
* setting button events for controlling the carousel.
*/
protected function createButtons():void
{
//Create Buttons
rightBtn = createButton();
leftBtn = createButton();
addChild(leftBtn);
addChild(rightBtn);
//Add button listeners
rightBtn.buttonMode = true;
leftBtn.buttonMode = true;
rightBtn.addEventListener(MouseEvent.CLICK, buttonClick);
leftBtn.addEventListener(MouseEvent.CLICK, buttonClick);
//Place buttons on stage
rightBtn.x = stage.stageWidth - 120;
leftBtn.x = 100;
rightBtn.y = stage.stageHeight / 2;
leftBtn.y = (stage.stageHeight / 2) + 20;
leftBtn.rotation = 180;
}
//Button actions
protected function buttonClick(evt:MouseEvent):void
{
switch (evt.target)
{
case rightBtn:
currentItem --;
break;
case leftBtn:
currentItem ++;
break;
}
rotate();
}
//Creates a simple arrow shape / returns the sprite
protected function createButton():Sprite
{
var btn:Sprite = new Sprite();
btn.graphics.beginFill(0x333333);
btn.graphics.moveTo(0, 0);
btn.graphics.lineTo(0, 20);
btn.graphics.lineTo(10, 10);
btn.graphics.lineTo(0, 0);
btn.graphics.endFill();
return btn;
}
}
}

Feel free to post links to ways you expand upon this file.

Delicious Digg This Post Facebook Stumble This Post

Fix Z-Sorting issues with the QuadrantRenderEngine

Published

Charlie

on November 28, 2009

in AS3, Actionscript 3.0, Examples, QuadrantRenderEngine, Tutorials and Z-Sorting Issues

. 1 Comment

Another way to solve your z-sorting issues is the use of the Quadrant Render Engine. The QuadrantRenderEngine only takes one parameter (type).

The three "types" of filtering available to you are:
QuadrantRenderEngine.ALL_FILTERS
QuadrantRenderEngine.CORRECT_Z_FILTER
QuadrantRenderEngine.QUAD_SPLIT_FILTER

For a full explanation of each of the 3 types available to you with this renderer take a look at this article.

The QuadrantRenderEngine use a technique of subdividing the screen into smaller and smaller regions to resolve potential conflicts between triangles.
blog.papervision3d.org

As also noted by others, this is a great tool to have around it does come with its performance issues. You may want to test out using ViewportLayers and optimizing in other areas.

Here is the simple code you need to change your renderer when extending BasicView.as:

PLAIN TEXT

Actionscript:

renderer = new QuadrantRenderEngine(QuadrantRenderEngine.ALL_FILTERS);

Here is the full code for this example:

PLAIN TEXT

Actionscript:

package
{
import flash.events.Event;
import org.papervision3d.materials.ColorMaterial;
import org.papervision3d.objects.primitives.Plane;
import org.papervision3d.objects.primitives.Sphere;
import org.papervision3d.render.QuadrantRenderEngine;
import org.papervision3d.view.BasicView;
import org.papervision3d.materials.BitmapFileMaterial;
public class Main extends BasicView
{
protected var sphere:Sphere
protected var plane:Plane;
protected var bitmapMaterial:BitmapFileMaterial;
protected var colorMaterial:ColorMaterial;
public function Main()
{
super();
//Try commenting out this line to see the issues.
renderer = new QuadrantRenderEngine(QuadrantRenderEngine.ALL_FILTERS);
createChildren();
commitProperties();
startRendering();
}
protected function createChildren():void
{
//Create a new 3D object
colorMaterial = new ColorMaterial(0x000000);
bitmapMaterial = new BitmapFileMaterial("images/ourtex.jpg")
//Create 3D Objects
plane = new Plane(colorMaterial,1000,1000,5,5)
sphere = new Sphere(bitmapMaterial, 50, 10,10);
//Add to scene
scene.addChild(plane);
scene.addChild(sphere);
}
protected function commitProperties():void
{
//Set some properties
sphere.scale = 4;
sphere.pitch( -10);
plane.rotationX = 60;
}
override protected function onRenderTick(event:Event = null):void
{
super.onRenderTick(event);
//Rotate
sphere.yaw(1);
}
}
}

Delicious Digg This Post Facebook Stumble This Post

Fix Z-Sorting Issues Using Viewport Layers

Published

Charlie

on November 27, 2009

in Actionscript 3 Papervision, Papervision 3D, Source Code, Tutorials and Z-Sorting Issues

. 7 Comments

Take a look at the sphere on the left. Ever had this happen to you and wondered if there was a good way to get rid of it? One of the ways we use is by adding a viewport layer. This works much the same as adding a new layer in flash or adding movieclip over another in AS3.

The best thing about this approach is that it's very simple and quick to implement:

PLAIN TEXT

Actionscript:

viewportLayer = viewport.getChildLayer(sphere, true);
viewportLayer.addDisplayObject3D(sphere);

For even more in depth discussion on viewport layers take a look at:
http://blog.zupko.info/?p=129

Here is the full class:

PLAIN TEXT

Actionscript:

package
{
import flash.events.Event;
import org.papervision3d.materials.ColorMaterial;
import org.papervision3d.objects.primitives.Plane;
import org.papervision3d.objects.primitives.Sphere;
import org.papervision3d.view.BasicView;
import org.papervision3d.objects.primitives.Cone;
import org.papervision3d.materials.BitmapFileMaterial;
import org.papervision3d.view.layer.ViewportLayer;
public class Main extends BasicView
{
protected var sphere:Sphere
protected var plane:Plane;
protected var bitmapMaterial:BitmapFileMaterial;
protected var colorMaterial:ColorMaterial;
protected var viewportLayer:ViewportLayer;
public function Main()
{
super();
createChildren();
commitProperties();
startRendering();
}
protected function createChildren():void
{
//Create a new 3D object
colorMaterial = new ColorMaterial(0x000000);
bitmapMaterial = new BitmapFileMaterial("images/ourtex.jpg")
//Create 3D Objects
plane = new Plane(colorMaterial,1000,1000,5,5)
sphere = new Sphere(bitmapMaterial, 50, 10,10);
//Add to scene
scene.addChild(plane);
scene.addChild(sphere);
//To see the z-sorting issue comment out these two lines
viewportLayer = viewport.getChildLayer(sphere, true);
viewportLayer.addDisplayObject3D(sphere);
}
protected function commitProperties():void
{
//Set some properties
sphere.scale = 4;
sphere.pitch( -10);
plane.rotationX = 60;
}
override protected function onRenderTick(event:Event = null):void
{
super.onRenderTick(event);
//Rotate
sphere.yaw(1);
}
}
}

Delicious Digg This Post Facebook Stumble This Post

Advanced Interactivity

Published

Charlie

on November 26, 2009

in Actionscript 3.0, Papervision 3D, Tutorials and TweenLite

. 8 Comments

This is just another example of how to do some advanced interactivity in Papervision 3D. This tutorial is just a slightly updated version of the #10 : Advanced Interactivity tutorial from a while back.

Here is what has been updated:
1) Removed InteractiveScene3DEvent and replaced it with standard MouseEvents
2) Updated to use papervision's BasicView.as class

For a full description of what is going on please refer back to this link: #10 : Advanced Interactivity

PLAIN TEXT

Actionscript:

package
{
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
import flash.text.TextField;
import org.papervision3d.materials.ColorMaterial;
import org.papervision3d.materials.MovieMaterial;
import org.papervision3d.materials.utils.MaterialsList;
import org.papervision3d.objects.primitives.Cube;
import org.papervision3d.view.BasicView;
/**
* ...
* @author Charlie Schulze, charlie[at]woveninteractive[dot]com
*/
public class Main extends BasicView
{
protected var cube:Cube;
protected var interactiveMats:Array;
protected var materialsList:MaterialsList;
protected var targetrotationX:Number;
protected var targetrotationY:Number;
protected var targetrotationZ:Number;
protected var tweening:Boolean;
public function Main():void
{
super();
init();
}
protected function init():void
{
createChildren();
startRendering();
}
protected function createChildren():void
{
//Set the viewport to interactive
viewport.interactive = true;
//Create Materials:
materialsList = new MaterialsList();
interactiveMats = ["front", "back", "left", "right", "bottom", "top"];
var colorsArray:Array = [0x76b6f8, 0x4291e1, 0x1f73c8, 0xe77111, 0xe8914c, 0xfad2b2];
for (var i:int = 0; i <interactiveMats.length; i++)
{
//Create a color box so we can use our MouseEvents
var colorBox:Sprite = new Sprite();
colorBox.graphics.beginFill(colorsArray[i]);
colorBox.graphics.drawRect(0, 0, 100, 100);
colorBox.graphics.endFill();
colorBox.name = interactiveMats[i];
//Add a textField for reference
var textField:TextField = new TextField()
colorBox.addChild(textField)
textField.text = interactiveMats[i];
//Add a MouseEvent to the Sprite
colorBox.mouseChildren = false;
colorBox.addEventListener(MouseEvent.CLICK, onMovieMatClicked);
//Create the MovieMat
var movieMat:MovieMaterial = new MovieMaterial(colorBox, true, true);
movieMat.interactive = true;
movieMat.smooth = true;
materialsList.addMaterial(movieMat, interactiveMats[i]);
}
//Create Cube
cube = new Cube(materialsList, 100, 100, 100);
//Add cube to the scene
scene.addChild(cube);
}
protected function onMovieMatClicked(evt:MouseEvent):void
{
if (tweening)
{
// Let it rotate again
tweening = false;
}
else
{
switch(evt.target.name) {
case "front":
targetrotationX = 0;
targetrotationY = 180;
targetrotationZ = 0;
tweening = true;
break;
case "back":
targetrotationX = 0;
targetrotationY = 0;
targetrotationZ = 0;
tweening = true;
break;
case "left":
targetrotationX = 0;
targetrotationY = -90;
targetrotationZ = 0;
tweening = true;
break;
case "right":
targetrotationX = 0;
targetrotationY = 90;
targetrotationZ = 0;
tweening = true;
break;
case "top":
targetrotationX = -90;
targetrotationY = 0;
targetrotationZ = 0;
tweening = true;
break;
case "bottom":
targetrotationX = 90;
targetrotationY = 0;
targetrotationZ = 180;
tweening = true;
break;
}
}
}
override protected function onRenderTick(event:Event = null):void
{
super.onRenderTick(event);
if (tweening) {
// If a face has been clicked
if (camera.zoom <230) {
// If the camera isn't zoomed enough then zoom in a bit more:
camera.zoom += Math.sqrt(230-camera.zoom)/5;
}
// Test each rotation and rotate it towards the target rotation:
// X axis:
if (cube.rotationX <targetrotationX)
{
cube.rotationX += Math.sqrt(targetrotationX-cube.rotationX);
cube.rotationX = Math.round(cube.rotationX);
}
else if (cube.rotationX> targetrotationX)
{
cube.rotationX -= Math.sqrt(cube.rotationX-targetrotationX);
cube.rotationX = Math.round(cube.rotationX);
}
// Y axis:
if (cube.rotationY <targetrotationY)
{
cube.rotationY += Math.sqrt(targetrotationY-cube.rotationY);
cube.rotationY = Math.round(cube.rotationY);
}
else if (cube.rotationY> targetrotationY)
{
cube.rotationY -= Math.sqrt(cube.rotationY-targetrotationY);
cube.rotationY = Math.round(cube.rotationY);
}
// Z axis:
if (cube.rotationZ <targetrotationZ)
{
cube.rotationZ += Math.sqrt(targetrotationZ-cube.rotationZ);
cube.rotationZ = Math.round(cube.rotationZ);
}
else if (cube.rotationZ> targetrotationZ)
{
cube.rotationZ -= Math.sqrt(cube.rotationZ-targetrotationZ);
cube.rotationZ = Math.round(cube.rotationZ);
}
}
else
{
// If the camera is zoomed in, it shouldn't be now
if (camera.zoom> 200)
{
// So zoom out a bit.
camera.zoom -= Math.sqrt(camera.zoom-2)/5;
}
// Rotate the cube a bit:
cube.rotationX += 2;
cube.rotationY += 2;
// Make sure that we dont "wind up" the rotation
if (cube.rotationX>= 360) cube.rotationX = 0;
if (cube.rotationY>= 360) cube.rotationY = 0;
}
}
}
}

Delicious Digg This Post Facebook Stumble This Post

2010 Flash And The City Speaker

RSS Feed

Tag Archive for 'Papervision Tutorial'

Adding XML to the Papervision Coverflow

A Simple Papervision Coverflow

A Simple Papervision Carousel

Fix Z-Sorting issues with the QuadrantRenderEngine

Fix Z-Sorting Issues Using Viewport Layers

Advanced Interactivity

Blogroll

Recent Posts

Pages

Tag Archive for 'Papervision Tutorial'

Adding XML to the Papervision Coverflow

A Simple Papervision Coverflow

A Simple Papervision Carousel

Fix Z-Sorting issues with the QuadrantRenderEngine

Fix Z-Sorting Issues Using Viewport Layers

Advanced Interactivity

Blogroll

Recent Posts

Tags

Pages