Monthly Archive for February, 2008

Panorama Viewer

Published

Charlie

on February 27, 2008

in Examples

. 11 Comments

*FIXED!!*

Here's a really simple example, all it does is texture a sphere and rotate it depending on what the camera is doing:

Click Here (1.3Mb download so I didn't embed this one)

Source Code (Uses the Base Class):

PLAIN TEXT

Actionscript:

/**
* ...
* @author Luke Mitchell
* @version 1
*/
package {
\timport org.papervision3d.materials.BitmapFileMaterial;
\timport flash.events.MouseEvent;
\timport org.papervision3d.materials.ColorMaterial;
\timport org.papervision3d.materials.utils.MaterialsList;
\timport org.papervision3d.objects.primitives.Cube;
\t
\tpublic class Main extends PaperBase {
\t\t
\t\tpublic var materials:MaterialsList = new MaterialsList(
\t\t{
\t\t\tfront: new BitmapFileMaterial("http://papervision2.com/wp-content/pano/s1.gif"),
\t\t\tback: new BitmapFileMaterial("http://papervision2.com/wp-content/pano/s3.gif"),
\t\t\tleft: new BitmapFileMaterial("http://papervision2.com/wp-content/pano/s4.gif"),
\t\t\tright: new BitmapFileMaterial("http://papervision2.com/wp-content/pano/s2.gif"),
\t\t\ttop: new ColorMaterial(0x000000),
\t\t\tbottom: new ColorMaterial(0x000000)
\t\t});
\t\tpublic var cubemap:Cube = new Cube(materials, 2000, 2000, 900, 5, 5, 5,Cube.ALL);
\t\t
\t\tpublic function Main() {
\t\t\tinit(600,300);
\t\t\tcubemap.x = 0;
\t\t\tcubemap.y = 0;
\t\t\tcubemap.z = 0;
\t\t\t
\t\t\tdefault_scene.addChild(cubemap);
\t\t\tdefault_camera.z = 0;
\t\t\tdefault_camera.x = 0;
\t\t\tdefault_camera.y = 0;
\t\t\tdefault_camera.lookAt(cubemap);
\t\t\t
\t\t\tdefault_camera.zoom = 5;
\t\t\tstage.addEventListener(MouseEvent.MOUSE_WHEEL, mWheel);
\t\t}
\t\t
\t\tpublic function mWheel(e:MouseEvent):void {
\t\t\tdefault_camera.zoom += e.delta / 5;
\t\t\tif (default_camera.zoom <5) {
\t\t\t\tdefault_camera.zoom = 5;
\t\t\t}else if (default_camera.zoom> 20) {
\t\t\t\tdefault_camera.zoom = 20;
\t\t\t}
\t\t}
\t\t
\t\toverride protected function processFrame():void {
\t\t\tcubemap.yaw( -((stage.mouseX - (stage.width / 2)) / stage.width)*4);
\t\t\tdefault_camera.rotationX = -((stage.mouseY - (stage.height / 2)) / stage.height) * (Math.sqrt(default_camera.zoom*6));
\t\t}
\t}
}

You can use this for pretty much any panoramic image, just change the image url and tweak it a bit :)

-Luke

Delicious Digg This Post Facebook Stumble This Post

11. Advanced Interactivity 2

Published

Charlie

on February 21, 2008

in Tutorials

. 57 Comments

**UPDATE
This tutorial has been updated

This tutorial will show you how to handle full interactivity on an objects surface, just as if it's a normal movieclip.

For my example, I've made this. The red spot in the centre is a button. You can click it to toggle it's glow on and off. The other button will reveal how it works!

There are other ways to do this, but I think this way is the easiest and most hassle-free, and it's pretty fast.

I've super-commented the source code, so from reading the comments in the code you should be able to figure out exactly what's going on.

The basic idea is, you add the movie clip which is being used as the texture to the scene, but make it invisible. You then move it so that your mouse is over the correct part of the movieclip, when your mouse touches the texture on the 3d model. I think the "Show Movieclip" button on the cube above will explain better than I can :)

PLAIN TEXT

Actionscript:

package {
import flash.display.Bitmap;
import flash.display.MovieClip;
import flash.events.MouseEvent;
import flash.filters.GlowFilter;
import org.papervision3d.materials.MovieMaterial;
import org.papervision3d.materials.utils.MaterialsList;
import org.papervision3d.objects.primitives.Cube;
import org.papervision3d.events.InteractiveScene3DEvent;
public class Main extends PaperBase {
// This is the movieclip that we'll use as the texture.
private var movie:MovieClip = new MovieClip();
// This movieclip will be completley transparent and will hold the
// texture movieclip, then move it to the correct loaction under the mouse.
private var movieParent:MovieClip = new MovieClip();
// These are buttons that I'm going to add to the texture movieclip
private var button:MovieClip = new MovieClip();
private var showbutton:MovieClip = new MovieClip();
// A "MovieMaterial" will use a movieclip as a texture.
private var mat:MovieMaterial;
// The cube that we're going to texture..
private var cube:Cube;
// This will import the file "E:/Papervision/images/showtex.jpg" to the project, and
// store the data in "ButtonIm". (This is the "Show Movieclip" Button)..
[Embed(source = "E:/Papervision/images/showtex.jpg")] private var ButtonIm:Class;
public function Main() {
// Initiate, 400px wide, 400px tall..
init(400, 400);
}
override protected function init3d():void {
// - See the prepareMovieclip function. This just builds the movieclip called "movie".
// You can use ANY movie clip for this..
prepareMovieclip();
// Prepare out moviematerial. Make it animated and interactive.
mat = new MovieMaterial(movie, false, true);
mat.interactive = true;
// Zoom in a bit..
default_camera.zoom = 5;
// Prepare the cube.
cube = new Cube(new MaterialsList( { all: mat } ), 500, 500, 500, 4, 4, 4);
// Listen for when the mouse is moved over the cube.
// Trigger the mMove function when this happens.
cube.addEventListener( InteractiveScene3DEvent.OBJECT_MOVE, mMove);
// Add the cube to the scene.
default_scene.addChild(cube);
// The movieParent movieclip will hold the movieclip which is being used
// as the texture. It will then move depending on the mouse posirion.
movieParent.addChild(movie);
// Make it invisible.
movieParent.alpha = 0;
// Add the movieParent movieclip to the stage.
addChild(movieParent);
}
private function prepareMovieclip():void {
// - This code will set up our movieclip which is going to be used
// as the texture for the cube.
// Draw Outline:
movie.graphics.beginFill(0xFFFFFF);
movie.graphics.drawRect(0, 0, 500, 500);
movie.graphics.endFill();
movie.graphics.beginFill(0x000000);
movie.graphics.drawRect(0, 0, 10, 500);
movie.graphics.drawRect(490, 0, 10, 500);
movie.graphics.drawRect(0, 0, 500, 10);
movie.graphics.drawRect(0, 490, 500, 10);
movie.graphics.endFill();
// Draw Circular Button:
button.graphics.beginFill(0xBB0000);
button.graphics.drawCircle(0, 0, 50);
button.graphics.endFill();
button.x = 250;
button.y = 250;
button.buttonMode = true;
// Load bitmap button texture:
var Bim:Bitmap = new ButtonIm();
// Draw "Show Movieclip" Texture:
showbutton.graphics.beginBitmapFill(Bim.bitmapData);
showbutton.graphics.drawRect(0,0,100,30);
showbutton.graphics.endFill();
showbutton.buttonMode = true;
showbutton.x = 380;
showbutton.y = 450;
// Add the buttons to the movieclip
movie.addChild(showbutton);
movie.addChild(button);
// -- Listen for the buttons to be clicked --
button.addEventListener(MouseEvent.CLICK, mClickButton);
showbutton.addEventListener(MouseEvent.CLICK, showHide);
// --
}
private function showHide( e:MouseEvent ):void {
// The "Show Movieclip" button has been clicked
if (movieParent.alpha == 0) { // If it's invisible,
movieParent.alpha = 0.2; // Make it slightly visible.
}else {
movieParent.alpha = 0; // Or make it invisible again
}
}
private function mClickButton(e:MouseEvent):void {
// The cental round button has been clicked.
if(button.name == "on"){
button.filters = null;
button.name = "off"
}else {
button.filters = [new GlowFilter(0x000000, 1, 15, 15, 10, 1)];
button.name = "on";
}
}
private function mMove( e:InteractiveScene3DEvent ):void {
// This code is run when the mouse is moved on the cube.
// This will move the movieclip to the right place beneath
// the mouse.
movieParent.x = root.mouseX -e.x;
movieParent.y = root.mouseY -e.y;
}
override protected function processFrame():void {
// Spin our cube a bit.
cube.yaw(0.25);
cube.pitch(0.25);
}
}
}

The image that's embedded in the code can be found here: showtex.jpg

Have fun! More Examples coming soon.

Delicious Digg This Post Facebook Stumble This Post

We Had Forums

Published

Charlie

on February 18, 2008

in News

. 5 Comments

We ~~have~~ had forums!

~~I've set up a Papervision 3d forum at http://papervision2.com/forum/~~

Hopefully these forums will help everyone to solve common problems that they're having with Papervision. I'm going to fill them with some problems which we've resolved in the past so they're all in one place.

I've set up Help, General Chat, Suggestions and Examples forums. If you can think of anything else that the forum needs then make a thread in the suggestions forum and I'll get round to it.

Hope you like it!

-Luke

Delicious Digg This Post Facebook Stumble This Post

10. Advanced Interactivity

Published

Charlie

on February 17, 2008

in Tutorials

. 72 Comments

**UPDATE
This tutorial has been updated:
Updates:
1) Removed InteractiveScene3DEvent and replaced it with standard MouseEvents
2) Updated to use papervision's BasicView.as class

Today we're going to learn how to handle more advanced interactivity. We'll be making something like this:

Click on a face of the cube to zoom into it. Click it again to make the cube spin again.

So, in this tutorial I'm going to show you exactly how to work out which material has been clicked on the cube and act accordingly.

If you haven't read it already, I strongly suggest that you read the Basic Interactivity tutorial first or you'll probably miss something.

Ok, so on to the code.

Firstly we'll want six materials to apply to each face of the cube. Here are mine, although you can create whatever materials you like:

PLAIN TEXT

Actionscript:

private var frontMaterial:BitmapFileMaterial = new BitmapFileMaterial("http://papervision2.com/wp-content/pvTex/front.jpg");
private var backMaterial:BitmapFileMaterial = new BitmapFileMaterial("http://papervision2.com/wp-content/pvTex/back.jpg");
private var leftMaterial:BitmapFileMaterial = new BitmapFileMaterial("http://papervision2.com/wp-content/pvTex/left.jpg");
private var rightMaterial:BitmapFileMaterial = new BitmapFileMaterial("http://papervision2.com/wp-content/pvTex/right.jpg");
private var topMaterial:BitmapFileMaterial = new BitmapFileMaterial("http://papervision2.com/wp-content/pvTex/top.jpg");
private var bottomMaterial:BitmapFileMaterial = new BitmapFileMaterial("http://papervision2.com/wp-content/pvTex/bottom.jpg");

So, in this code I'm just loading six images from my server to use as each face.

Also, add the following declaration beneath the texture declarations to hold our Cube object:

PLAIN TEXT

Actionscript:

private var cube:Cube;

Now we need to set up the 3d initiation code. In this code we will firstly set all of our materials as interactive, and then give each of our materials a name. This is VERY important to be able to easily find out which material has been clicked. If we didn't give each material a name then we wouldn't be able to easily work out which face has been clicked.

So, add the following code to your init3d() function:

PLAIN TEXT

Actionscript:

override protected function init3d():void {
// We need to be able to identify each side. We'll do this
// by asssigning names to each material. During this process
// we'll also make the materials interactive.
frontMaterial.interactive = true;
frontMaterial.name = "front";
backMaterial.interactive = true;
backMaterial.name = "back";
leftMaterial.interactive = true;
leftMaterial.name = "left";
rightMaterial.interactive = true;
rightMaterial.name = "right";
topMaterial.interactive = true;
topMaterial.name = "top";
bottomMaterial.interactive = true;
bottomMaterial.name = "bottom";
// ---------------------------------------------
cube = new Cube(new MaterialsList( {
front: frontMaterial,
back: backMaterial,
left: leftMaterial,
right: rightMaterial,
top: topMaterial,
bottom: bottomMaterial
} ), 500, 500, 500, 3, 3, 3);
cube.addEventListener( InteractiveScene3DEvent.OBJECT_PRESS, onPress);
default_scene.addChild(cube);
}

So, In this code, we've set each material as interactive, given each one a sensible name, and initialised our cube with the materials assigned to the correct faces.

We then add an event listener to trigger the "onPress" event when the cube is clicked, then finally we add the cube to the scene.

We've now got a cube with six materials on it listening for a click event.

Now, the code which will let us work out which face has been clicked:

PLAIN TEXT

Actionscript:

private function onPress( e:InteractiveScene3DEvent ):void {
switch(e.face3d.material.name) {
case "front":
// This code will be run when the front face is clicked
break;
case "back":
// This code will be run when the back face is clicked
break;
case "left":
// This code will be run when the left face is clicked
break;
case "right":
// This code will be run when the right face is clicked
break;
case "top":
// This code will be run when the top face is clicked
break;
case "bottom":
// This code will be run when the bottom face is clicked
break;
}
}

Pretty self explanitary. The "e" variable in this code holds lots of data about the click event, including which material has been clicked, so, because we know which material is on each face, we can tell by the materials name which face has been clicked!

With a little bit of code, you can make a nice spinning cube gallery like the example above:

Here is my final code, have fun!

PLAIN TEXT

Actionscript:

package {
import flash.display.DisplayObject;
import org.papervision3d.materials.BitmapFileMaterial;
import org.papervision3d.materials.utils.MaterialsList;
import org.papervision3d.events.InteractiveScene3DEvent;
import org.papervision3d.objects.primitives.Cube;
public class Main extends PaperBase {
private var frontMaterial:BitmapFileMaterial = new BitmapFileMaterial("http://papervision2.com/wp-content/pvTex/front.jpg");
private var backMaterial:BitmapFileMaterial = new BitmapFileMaterial("http://papervision2.com/wp-content/pvTex/back.jpg");
private var leftMaterial:BitmapFileMaterial = new BitmapFileMaterial("http://papervision2.com/wp-content/pvTex/left.jpg");
private var rightMaterial:BitmapFileMaterial = new BitmapFileMaterial("http://papervision2.com/wp-content/pvTex/right.jpg");
private var topMaterial:BitmapFileMaterial = new BitmapFileMaterial("http://papervision2.com/wp-content/pvTex/top.jpg");
private var bottomMaterial:BitmapFileMaterial = new BitmapFileMaterial("http://papervision2.com/wp-content/pvTex/bottom.jpg");
private var targetrotationX:Number = 0;
private var targetrotationY:Number = 0;
private var targetrotationZ:Number = 0;
private var tweening:Boolean = false;
private var cube:Cube;
public function Main() {
init(400, 400);
}
override protected function init3d():void {
// We need to be able to identify each side. We'll do this
// by asssigning names to each material. During this process
// we'll also make the materials interactive.
frontMaterial.interactive = true;
frontMaterial.name = "front";
backMaterial.interactive = true;
backMaterial.name = "back";
leftMaterial.interactive = true;
leftMaterial.name = "left";
rightMaterial.interactive = true;
rightMaterial.name = "right";
topMaterial.interactive = true;
topMaterial.name = "top";
bottomMaterial.interactive = true;
bottomMaterial.name = "bottom";
// ---------------------------------------------
cube = new Cube(new MaterialsList( {
front: frontMaterial,
back: backMaterial,
left: leftMaterial,
right: rightMaterial,
top: topMaterial,
bottom: bottomMaterial
} ), 500, 500, 500, 3, 3, 3);
// Listen for the click:
cube.addEventListener( InteractiveScene3DEvent.OBJECT_PRESS, onPress);
// Add to scene:
default_scene.addChild(cube);
}
private function onPress( e:InteractiveScene3DEvent ):void {
// If the cube has been moved to the front:
if (tweening) {
// Let it rotate again
tweening = false;
}else {
// Find which rotation we need to be able to see
// the face image:
switch(e.face3d.material.name) {
case "front":
targetrotationX = 0;
targetrotationY = 180;
targetrotationZ = 0;
tweening = true;
break;
case "back":
targetrotationX = 0;
targetrotationY = 0;
targetrotationZ = 0;
tweening = true;
break;
case "left":
targetrotationX = 0;
targetrotationY = -90;
targetrotationZ = 0;
tweening = true;
break;
case "right":
targetrotationX = 0;
targetrotationY = 90;
targetrotationZ = 0;
tweening = true;
break;
case "top":
targetrotationX = 90;
targetrotationY = 0;
targetrotationZ = 0;
tweening = true;
break;
case "bottom":
targetrotationX = -90;
targetrotationY = 0;
targetrotationZ = 180;
tweening = true;
break;
}
}
}
override protected function processFrame():void {
if (tweening) {
// If a face has been clicked
if (default_camera.zoom <6.8) {
// If the camera isn't zoomed enough then zoom in a bit more:
default_camera.zoom += Math.sqrt(6.8-default_camera.zoom)/5;
}
// Test each rotation and rotate it towards the target rotation:
// X axis:
if (cube.rotationX <targetrotationX) {
cube.rotationX += Math.sqrt(targetrotationX-cube.rotationX);
cube.rotationX = Math.round(cube.rotationX);
}else if (cube.rotationX> targetrotationX) {
cube.rotationX -= Math.sqrt(cube.rotationX-targetrotationX);
cube.rotationX = Math.round(cube.rotationX);
}
// Y axis:
if (cube.rotationY <targetrotationY) {
cube.rotationY += Math.sqrt(targetrotationY-cube.rotationY);
cube.rotationY = Math.round(cube.rotationY);
}else if (cube.rotationY> targetrotationY) {
cube.rotationY -= Math.sqrt(cube.rotationY-targetrotationY);
cube.rotationY = Math.round(cube.rotationY);
}
// Z axis:
if (cube.rotationZ <targetrotationZ) {
cube.rotationZ += Math.sqrt(targetrotationZ-cube.rotationZ);
cube.rotationZ = Math.round(cube.rotationZ);
}else if (cube.rotationZ> targetrotationZ) {
cube.rotationZ -= Math.sqrt(cube.rotationZ-targetrotationZ);
cube.rotationZ = Math.round(cube.rotationZ);
}
}else {
// If the camera is zoomed in, it shouldn't be now
if (default_camera.zoom> 2) {
// So zoom out a bit.
default_camera.zoom -= Math.sqrt(default_camera.zoom-2)/5;
}
// Rotate the cube a bit:
cube.rotationX += 2;
cube.rotationY += 2;
// Make sure that we dont "wind up" the rotation
if (cube.rotationX>= 360) cube.rotationX = 0;
if (cube.rotationY>= 360) cube.rotationY = 0;
}
}
}
}

Delicious Digg This Post Facebook Stumble This Post

9. Basic Interactivity

Published

Charlie

on February 9, 2008

in Tutorials

. 72 Comments

In this tutorial, we're going to learn how to handle "interactive scene3d events", in particular the events which occur when your mouse moves over an object, out of an object and clicks an object. We're going to make something like this:

When you place your mouse over the plane, the material will change. When you click it, it will spin in the opposite direction.

Unfortunately we have to edit the base class.. again.. All we need to do is change one line so that the viewport becomes interactive when we initialise it.

Open up PaperBase.as, and find this line:

PLAIN TEXT

Actionscript:

viewport = new Viewport3D(vpWidth, vpHeight);

Swap it for this line:

PLAIN TEXT

Actionscript:

viewport = new Viewport3D(vpWidth, vpHeight, false, true);

This will make the viewport interactive, which means it can trigger events.

Now that you've updated the base class, create a new project. Make the Main class extend PaperBase as usual and then add the following imports:

PLAIN TEXT

Actionscript:

import org.papervision3d.materials.BitmapFileMaterial;
import org.papervision3d.objects.DisplayObject3D;
import org.papervision3d.events.InteractiveScene3DEvent;
import org.papervision3d.objects.primitives.Plane;

Now, add the following declarations under "public class Main extends PaperBase {" :

PLAIN TEXT

Actionscript:

private var ourMaterial:BitmapFileMaterial = new BitmapFileMaterial("http://papervision2.com/wp-content/pvTex/front.jpg");
private var ourOverMaterial:BitmapFileMaterial = new BitmapFileMaterial("http://papervision2.com/wp-content/pvTex/front_over.jpg");
private var yawspeed:Number = 5;
private var plane :DisplayObject3D;

ourMaterial is the material that we'll put onto the plane.
ourOverMaterial is the material that will be activated on mouse over.
We'll load both of these materials from files on my server.
yawspeed will be how much we're going to yaw() the plane by each frame
and "plane" will be the plane.

This next function will show you how to make the material interactive, and how to add an event listener to the stage:

PLAIN TEXT

Actionscript:

override protected function init3d():void {
ourMaterial.interactive = true; // You need to set the interactive property of the materal to true.
ourMaterial.doubleSided = true; // We want to be able to see both sides of the plane
ourOverMaterial.interactive = true; // Same for the mouseover material
ourOverMaterial.doubleSided = true;
plane = new Plane(ourMaterial, 1000, 1000, 4, 4); // Create a new plane
default_scene.addChild(plane); // Add it to the scene
// These lines add event listeners to the plane which will trigger the functions on the event specified.
plane.addEventListener( InteractiveScene3DEvent.OBJECT_PRESS, onPress ); // Will trigger "onPress" when the object is pressed (clicked)
plane.addEventListener( InteractiveScene3DEvent.OBJECT_OVER, onOver ); // Will trigger "onOver" when the mouse rolls over the object
plane.addEventListener( InteractiveScene3DEvent.OBJECT_OUT, onOut ); // Will trigger "onOut" when the mouse rolls out of the object
}

I've commented the code so it should be easy to understand.

Now we need to add the "on..." functions. You can do whatever you want in these functions, but in this tutorial we're going to make the effect like above.

PLAIN TEXT

Actionscript:

private function onOver ( e:InteractiveScene3DEvent ):void {
plane.material = ourOverMaterial; // Change the material to "ourOverMaterial"
}
private function onOut ( e:InteractiveScene3DEvent ):void {
plane.material = ourMaterial; // Change the material back to "ourMaterial"
}
private function onPress( e:InteractiveScene3DEvent ):void {
yawspeed *= -1; // Reverse the yaw speed
}

Finally, we need to add the processFrame code, to rotate the plane by the angle "yawspeed".

PLAIN TEXT

Actionscript:

override protected function processFrame():void {
plane.yaw(yawspeed);
}

Done! Run the project and you should see the result like above. Here's the complete code:

PLAIN TEXT

Actionscript:

package {
import org.papervision3d.materials.BitmapFileMaterial;
import org.papervision3d.objects.DisplayObject3D;
import org.papervision3d.events.InteractiveScene3DEvent;
import org.papervision3d.objects.primitives.Plane;
public class Main extends PaperBase {
private var ourMaterial:BitmapFileMaterial = new BitmapFileMaterial("http://papervision2.com/wp-content/pvTex/front.jpg");
private var ourOverMaterial:BitmapFileMaterial = new BitmapFileMaterial("http://papervision2.com/wp-content/pvTex/front_over.jpg");
private var yawspeed:Number = 5;
private var plane :DisplayObject3D;
public function Main() {
init();
}
override protected function init3d():void {
ourMaterial.interactive = true;
ourMaterial.doubleSided = true;
ourOverMaterial.interactive = true;
ourOverMaterial.doubleSided = true;
plane = new Plane(ourMaterial, 1000, 1000, 4, 4);
default_scene.addChild(plane);
plane.addEventListener( InteractiveScene3DEvent.OBJECT_PRESS, onPress );
plane.addEventListener( InteractiveScene3DEvent.OBJECT_OVER, onOver );
plane.addEventListener( InteractiveScene3DEvent.OBJECT_OUT, onOut );
}
private function onOver ( e:InteractiveScene3DEvent ):void {
plane.material = ourOverMaterial; // Change the material to "ourOverMaterial"
}
private function onOut ( e:InteractiveScene3DEvent ):void {
plane.material = ourMaterial; // Change the material back to "ourMaterial"
}
private function onPress( e:InteractiveScene3DEvent ):void {
yawspeed *= -1; // Reverse the yaw speed
}
override protected function processFrame():void {
plane.yaw(yawspeed);
}
}
}

Delicious Digg This Post Facebook Stumble This Post

Poll Results

Published

Charlie

on February 9, 2008

in News

. 0 Comments

Hi,

Thanks for voting! The poll results are in, and I'll be publishing the next tutorials in this order:

Basic Interactivity
Advanced Interactivity
Advanced Texturing
Creating an interface
Using Multiple Cameras and Scenes
I'll publish more effects and shading examples

Interactivity tutorials coming right up!!

Be sure to check back later!

- Luke

Delicious Digg This Post Facebook Stumble This Post

2010 Flash And The City Speaker

RSS Feed

Monthly Archive for February, 2008

Panorama Viewer

11. Advanced Interactivity 2

We Had Forums

10. Advanced Interactivity

9. Basic Interactivity

Poll Results

Blogroll

Recent Posts

Pages

Monthly Archive for February, 2008

Panorama Viewer

11. Advanced Interactivity 2

We Had Forums

10. Advanced Interactivity

9. Basic Interactivity

Poll Results

Blogroll

Recent Posts

Tags

Pages